Deploying the WDS API Server with a Helm Chart

Deploy to Kubernetes using the WDS Helm Chart — suitable for staging and production with scaling and resilience.

By default, the Helm chart is configured to deploy the WDS API Server in SingleService mode — deploying one instance of the Solidstack service. Only one configuration parameter is required: a MongoDB connection string. Kindly review the Third-Party Components for compatible versions.

To deploy WDS API Server in MultiService mode, a license key is required. Contact us for a license key.
If you find an error in the Helm chart (or in the WDS API Server itself), or if you have specific requirements that need to be added to the Helm chart, kindly use the Issues.

Deployment options

There are several ways to deploy the WDS Helm Chart.

Deploying using Helm CLI

To deploy the WDS API Server using the Helm CLI, run the following commands:

IMPORTANT! Ensure you have access to a Kubernetes cluster.

# Add a repository
helm repo add webdatasource https://webdatasource.github.io/wds.helm

# Update your local repository cache
helm repo update

# Search for the chart to verify it's available
helm search repo webdatasource --version 1.3.0

# Install the chart
helm install wds-server --version 1.3.0 webdatasource/wds-helm-chart \
    --namespace webdatasource --create-namespace \
    --set global.registry="docker.io" \
    --set global.coreServices.databases.mongodb.connectionString="mongodb+srv://<user>:<password>@<host>/WebDataSource?appName=<cluster>&readPreference=secondary"

Deploying using Terraform

IMPORTANT! Ensure you have helm provider configured in your terraform project.

• Terraform (SingleService)
• Terraform (MultiService)

variable "mongodb_connection_string" {
  description = "MongoDB connection string"
  type        = string
  sensitive   = true
}

variable "registry" {
  description = "Docker registry of WDS API Server service images"
  type        = string
  default     = "docker.io"
}

variable "helm_chart_version" {
  description = "Helm chart version for WDS API Server deployment"
  type        = string
  default     = "1.3.0"
}

variable "create_namespace" {
  description = "Namespace and ingress configuration for WDS API Server deployment. Set `create_namespace` to false to deploy in an existing namespace"
  type        = bool
  default     = true
}

variable "namespace" {
  description = "Namespace for WDS API Server deployment"
  type        = string
  default     = "webdatasource"
}

variable "enable_ingress" {
  description = "Enable or disable ingress for WDS API Server deployment"
  type        = bool
  default     = true
}

# Kubernetes namespace resource
resource "kubernetes_namespace" "webdatasource" {
  count = var.create_namespace ? 1 : 0
  metadata {
    name = var.namespace
  }
}

# Helm release resource
resource "helm_release" "wds-server" {
  name       = "wds-server"
  repository = "https://webdatasource.github.io/wds.helm"
  chart      = "wds-helm-chart"
  version    = var.helm_chart_version

  namespace        = var.namespace
  create_namespace = false

  values = [
    yamlencode({
      global = {
        registry = var.registry
        ingress = {
          enabled = var.enable_ingress
        }
      }
    }),
    sensitive(yamlencode({
      global = {
        coreServices = {
          databases = {
            mongodb = {
              connectionString = var.mongodb_connection_string
            }
          }
        }
      }
    }))
  ]

  depends_on = [
    kubernetes_namespace.webdatasource
  ]
}

variable "license_key" {
  description = "WebDataSource license key"
  type        = string
  sensitive   = true
}

variable "embedding_service_url" {
  description = "Embedding service URL"
  type        = string
}

variable "embedding_service_api_key" {
  description = "Embedding service API key"
  type        = string
  sensitive   = true
  default     = ""
}

variable "mongodb_connection_string" {
  description = "MongoDB connection string"
  type        = string
  sensitive   = true
}

variable "registry" {
  description = "Docker registry of WDS API Server service images"
  type        = string
  default     = "docker.io"
}

variable "helm_chart_version" {
  description = "Helm chart version for WDS API Server deployment"
  type        = string
  default     = "1.3.0"
}

variable "create_namespace" {
  description = "Namespace and ingress configuration for WDS API Server deployment. Set `create_namespace` to false to deploy in an existing namespace"
  type        = bool
  default     = true
}

variable "namespace" {
  description = "Namespace for WDS API Server deployment"
  type        = string
  default     = "webdatasource"
}

variable "enable_ingress" {
  description = "Enable or disable ingress for WDS API Server deployment"
  type        = bool
  default     = true
}

# Kubernetes namespace resource
resource "kubernetes_namespace" "webdatasource" {
  count = var.create_namespace ? 1 : 0
  metadata {
    name = var.namespace
  }
}

# Helm release resource
resource "helm_release" "wds-server" {
  name       = "wds-server"
  repository = "https://webdatasource.github.io/wds.helm"
  chart      = "wds-helm-chart"
  version    = var.helm_chart_version

  namespace        = var.namespace
  create_namespace = false

  values = [
    yamlencode({
      global = {
        registry = var.registry
        ingress = {
          enabled = var.enable_ingress
        }
        coreServices = {
          mode = "MultiService"
          search = {
            enabled = true
            embeddingService = {
              url = var.embedding_service_url
            }
          }
        }
      }
    }),
    sensitive(yamlencode({
      global = {
        coreServices = {
          license = {
            key = var.license_key
          }
          databases = {
            mongodb = {
              connectionString = var.mongodb_connection_string
            }
          }
          search = {
            embeddingService = {
              apiKey = var.embedding_service_api_key
            }
          }
        }
      }
    }))
  ]

  depends_on = [
    kubernetes_namespace.webdatasource
  ]
}

NOTE This code can be used to create a dedicated Terraform Module for WDS API Server.

Configuration

The following configuration parameters can be set via the values.yaml file:

coreServices and auxiliaryServices sections in the values file can be used to override the global configuration for a particular service.

Accessing the WDS API Server instance

When the helm release has been deployed to a Kubernetes cluster, use the following command to get access URLs:

NAMESPACE=webdatasource # Change the namespce if necessary
SCHEME=$(kubectl get ing webdatasource -n $NAMESPACE -o jsonpath='{.spec.tls[0].hosts[0]}')
SCHEME=$([ -n "$SCHEME" ] && echo https || echo http)
HOST=$(kubectl get ing webdatasource -n $NAMESPACE -o jsonpath='{.spec.rules[0].host}')
if [ -z "$HOST" ]; then
  HOST=$(kubectl get ing webdatasource -n $NAMESPACE -o jsonpath='{.status.loadBalancer.ingress[0].hostname}')
  [ -z "$HOST" ] && HOST=$(kubectl get ing webdatasource -n $NAMESPACE -o jsonpath='{.status.loadBalancer.ingress[0].ip}')
  [ -z "$HOST" ] && HOST=localhost
fi
echo
kubectl get ing webdatasource -n $NAMESPACE -o jsonpath='{range .spec.rules[*].http.paths[*]}{.path}/{"\n"}{end}' | awk -v s="$SCHEME" -v h="$HOST" '{print s"://"h $0}'

The result should look like this:

http(s)://[your-host]/playground/
http(s)://[your-host]/docs/
http(s)://[your-host]/api/
http(s)://[your-host]/mcp/

• /playground/ is used to access Playground
• /docs/ is used to access Docs
• /mcp/ is used to acceess MCP Server
• /api/ is used by MS SQL CRL Functions